ScrollBar.qml Example File | Qt Quick 5.9

Qt 5.9 | Qt Quick | Qt Quick Demo - RSS News | ScrollBar.qml Example File

Qt 5.9.2 Reference Documentation

# ScrollBar.qml Example File

demos/rssnews/content/ScrollBar.qml

      /****************************************************************************
      **
      ** Copyright (C) 2015 The Qt Company Ltd.
      ** Contact: http://www.qt.io/licensing/
      **
      ** This file is part of the examples of the Qt Toolkit.
      **
      ** $QT_BEGIN_LICENSE:BSD$
      ** You may use this file under the terms of the BSD license as follows:
      **
      ** "Redistribution and use in source and binary forms, with or without
      ** modification, are permitted provided that the following conditions are
      ** met:
      **   * Redistributions of source code must retain the above copyright
      **     notice, this list of conditions and the following disclaimer.
      **   * Redistributions in binary form must reproduce the above copyright
      **     notice, this list of conditions and the following disclaimer in
      **     the documentation and/or other materials provided with the
      **     distribution.
      **   * Neither the name of The Qt Company Ltd nor the names of its
      **     contributors may be used to endorse or promote products derived
      **     from this software without specific prior written permission.
      **
      **
      ** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
      ** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
      ** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
      ** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
      ** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
      ** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
      ** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
      ** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
      ** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
      ** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
      ** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE."
      **
      ** $QT_END_LICENSE$
      **
      ****************************************************************************/

      import QtQuick 2.2

      Item {
          id: container

          property variant scrollArea
          property int orientation: Qt.Vertical

          opacity: 0

          function position()
          {
              var ny = 0;
              if (container.orientation == Qt.Vertical)
                  ny = scrollArea.visibleArea.yPosition * container.height;
              else
                  ny = scrollArea.visibleArea.xPosition * container.width;

              if (ny > 2)
                  return ny;
              else
                  return 2;
          }

          function size()
          {
              var nh, ny;

              if (container.orientation == Qt.Vertical)
                  nh = scrollArea.visibleArea.heightRatio * container.height;
              else
                  nh = scrollArea.visibleArea.widthRatio * container.width;

              if (container.orientation == Qt.Vertical)
                  ny = scrollArea.visibleArea.yPosition * container.height;
              else
                  ny = scrollArea.visibleArea.xPosition * container.width;

              if (ny > 3) {
                  var t;
                  if (container.orientation == Qt.Vertical)
                      t = Math.ceil(container.height - 3 - ny);
                  else
                      t = Math.ceil(container.width - 3 - ny);
                  if (nh > t)
                      return t;
                  else
                      return nh;
              } else
                  return nh + ny;
          }

          Rectangle { anchors.fill: parent; color: "Black"; opacity: 0.3 }

          BorderImage {
              source: "images/scrollbar.png"
              border { left: 1; right: 1; top: 1; bottom: 1 }
              x: container.orientation == Qt.Vertical ? 2 : position()
              y: container.orientation == Qt.Vertical ? position() : 2
              width: container.orientation == Qt.Vertical ? container.width - 4 : size()
              height: container.orientation == Qt.Vertical ? size() : container.height - 4
          }

          states: State {
              name: "visible"
              when: container.orientation == Qt.Vertical ?
                        scrollArea.movingVertically :
                        scrollArea.movingHorizontally
              PropertyChanges { target: container; opacity: 1.0 }
          }

          transitions: Transition {
              from: "visible"; to: ""
              NumberAnimation { properties: "opacity"; duration: 600 }
          }
      }